/*--+------------------------------------------------------------+--*/
/*--+   PROGRAM ID : $CPYOUTQ                                    +--*/
/*--+ PROGRAM NAME : CL OF COPY OUTPUT QUEUE.                    +--*/
/*--+------------------------------------------------------------+--*/
/*--+      VERSION : 1.0 (1999/08/17)                            +--*/
/*--+------------------------------------------------------------+--*/
PGM PARM(&FR_OUTQLIB &TO_OUTQLIB &USER &FORM &USRDTA)

/*--+------------------------------------------------------------+--*/
/*  + DECLARATION                                                +  */
/*--+------------------------------------------------------------+--*/

/*- COMMAND PARAMETERS FOR THIS PROGRAM ----------------------------*/
DCL VAR(&FR_OUTQLIB) TYPE(*CHAR) LEN(  20  )  /* FROM OUTQ & LIBRARY*/
    DCL VAR(&FR_OUTQ   ) TYPE(*CHAR) LEN(  10  ) /* FROM OUTQ       */
    DCL VAR(&FR_LIB    ) TYPE(*CHAR) LEN(  10  ) /* FROM LIBRARY    */
DCL VAR(&TO_OUTQLIB) TYPE(*CHAR) LEN(  20  )  /* TO   OUTQ & LIBRARY*/
    DCL VAR(&TO_OUTQ   ) TYPE(*CHAR) LEN(  10  ) /* TO   OUTQ       */
    DCL VAR(&TO_LIB    ) TYPE(*CHAR) LEN(  10  ) /* TO   LIBRARY    */
DCL VAR(&USER      ) TYPE(*CHAR) LEN(  10  )  /* USER               */
DCL VAR(&FORM      ) TYPE(*CHAR) LEN(  10  )  /* FORM TYPE          */
DCL VAR(&USRDTA    ) TYPE(*CHAR) LEN(  10  )  /* USER DATA          */

/*- SHARED VARIABLES FOR THIS PROGRAM ------------------------------*/
DCL VAR(&SH_MSG    ) TYPE(*CHAR) LEN(  80  ) /* MESSAGE             */

/*--+------------------------------------------------------------+--*/
/*  + START OF PROGRAM                                           +  */
/*--+------------------------------------------------------------+--*/

/*--+------------------------------------------------------------+--*/
/*  + INITIALIZE                                                 +  */
/*--+------------------------------------------------------------+--*/

/*- PREPARATION FOR COMMAND PARAMETER ------------------------------*/
IF (%SST(&TO_OUTQLIB 1 10) *EQ '*JOB') DO
    RTVJOBA OUTQ(&TO_OUTQ   ) OUTQLIB(&TO_LIB    )
    CHGVAR  VAR(%SST(&TO_OUTQLIB  1 10)) VALUE(&TO_OUTQ   )
    CHGVAR  VAR(%SST(&TO_OUTQLIB 11 10)) VALUE(&TO_LIB    )
ENDDO


/*- DIVISION OF COMMAND PARAMETER ----------------------------------*/
CHGVAR VAR(&FR_OUTQ   )             VALUE(%SST(&FR_OUTQLIB  1 10))
CHGVAR VAR(&FR_LIB    )             VALUE(%SST(&FR_OUTQLIB 11 10))

CHGVAR VAR(&TO_OUTQ   )             VALUE(%SST(&TO_OUTQLIB  1 10))
CHGVAR VAR(&TO_LIB    )             VALUE(%SST(&TO_OUTQLIB 11 10))


/*- CHECK OF COMMAND PARAMETER -------------------------------------*/
/* FROM OUTQ */
IF ((&FR_LIB *NE '*LIBL') *AND (&FR_LIB *NE '*CURLIB')) DO
    CHKOBJ OBJ(&FR_LIB) OBJTYPE(*LIB)
        MONMSG MSGID(CPF9801) EXEC(DO)
            RCVMSG MSGQ(*PGMQ) RMV(*YES)
            /* MSG: LIBRARY NOT FOUND */
            SNDPGMMSG MSGID(CPF9810) MSGF(QCPFMSG)       +
                                     MSGDTA(&FR_LIB)    +
                                     MSGTYPE(*ESCAPE)
        ENDDO
ENDDO

CHKOBJ OBJ(&FR_LIB/&FR_OUTQ) OBJTYPE(*OUTQ)
    MONMSG MSGID(CPF9801) EXEC(DO)
        RCVMSG MSGQ(*PGMQ) RMV(*YES)
        /* MSG: OUTPUT QUEUE IN LIBRARY NOT FOUND */
        SNDPGMMSG MSGID(CPF3357) MSGF(QCPFMSG)       +
                                 MSGDTA(&FR_OUTQLIB) +
                                 MSGTYPE(*ESCAPE)
    ENDDO

/* TOOUTQ */
IF ((&TO_LIB *NE '*LIBL') *AND (&TO_LIB *NE '*CURLIB')) DO
    CHKOBJ OBJ(&TO_LIB) OBJTYPE(*LIB)
        MONMSG MSGID(CPF9801) EXEC(DO)
            RCVMSG MSGQ(*PGMQ) RMV(*YES)
            /* MSG: LIBRARY NOT FOUND */
            SNDPGMMSG MSGID(CPF9810) MSGF(QCPFMSG)       +
                                     MSGDTA(&TO_LIB)    +
                                     MSGTYPE(*ESCAPE)
        ENDDO
ENDDO

CHKOBJ OBJ(&TO_LIB/&TO_OUTQ) OBJTYPE(*OUTQ)
    MONMSG MSGID(CPF9801) EXEC(DO)
        RCVMSG MSGQ(*PGMQ) RMV(*YES)
        /* MSG: OUTPUT QUEUE IN LIBRARY NOT FOUND */
        SNDPGMMSG MSGID(CPF3357) MSGF(QCPFMSG)       +
                                 MSGDTA(&TO_OUTQLIB) +
                                 MSGTYPE(*ESCAPE)
    ENDDO


/*- CREATION OF TEMPORARY FILE -------------------------------------*/
/*CRTPF  FILE(QTEMP/CPYOUTQ_F) RCDLEN(4083) +
       IGCDTA(*YES) TEXT('CREATED BY CPYOUTQ') MAXMBRS(*NOMAX) */
 /*   MONMSG MSGID(CPF0000)                                      */


/*--+------------------------------------------------------------+--*/
/*  + M A I N                                                    +  */
/*--+------------------------------------------------------------+--*/
SAVOUTQ OUTQ(&FR_LIB/&FR_OUTQ)                   +
        TOFILE(QTEMP/CPYOUTQ_F) MBROPT(*REPLACE) +
        USER(&USER) FORM(&FORM) USRDTA(&USRDTA)
    MONMSG MSGID(CPF0000) EXEC(DO)
        CHGVAR VAR(&SH_MSG    )  VALUE('SEE THE PREVIOUSLY '  *BCAT +
                                       'LISTED MESSAGE '      *BCAT +
                                       'IN THE JOBLOG'              )

        SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG)    +
                                 MSGDTA(&SH_MSG)  +
                                 MSGTYPE(*ESCAPE)
    ENDDO


RSTOUTQ FILE(QTEMP/CPYOUTQ_F) RSTOUTQ(&TO_LIB/&TO_OUTQ)
    MONMSG MSGID(CPF0000) EXEC(DO)
        CHGVAR VAR(&SH_MSG    )  VALUE('SEE THE PREVIOUSLY '  *BCAT +
                                       'LISTED MESSAGE '      *BCAT +
                                       'IN THE JOBLOG'              )

        SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG)    +
                                 MSGDTA(&SH_MSG)  +
                                 MSGTYPE(*ESCAPE)
    ENDDO


/* SUCCESSFUL MESSAGE */
CHGVAR VAR(&SH_MSG    )  VALUE('SPOOLED FILES COPIED ' *BCAT +
                               'FROM OUTQ '            *BCAT +
                               &FR_OUTQ                *BCAT +
                               'IN '                   *BCAT +
                               &FR_LIB                 *BCAT +
                               'TO OUTQ '              *BCAT +
                               &TO_OUTQ                *BCAT +
                               'IN '                   *BCAT +
                               &TO_LIB                       )

SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG)    +
                         MSGDTA(&SH_MSG)  +
                         MSGTYPE(*COMP  )


/*--+------------------------------------------------------------+--*/
/*  + END OF PROGRAM                                             +  */
/*--+------------------------------------------------------------+--*/
#_EXIT_:
ENDPGM