/*--+------------------------------------------------------------+--*/
/*--+   PROGRAM ID : $DSPPFR                                     +--*/
/*--+ PROGRAM NAME : CL OF DISPLAY NUMBER OF PF RECORDS          +--*/
/*--+------------------------------------------------------------+--*/
/*--+      VERSION : 1.1 (98/10/16) ADDED OVRDBF AND DLTOVR      +--*/
/*--+                1.0 (98/10/12)                              +--*/
/*--+------------------------------------------------------------+--*/
PGM PARM(&FILEANDLIB)

/*--+------------------------------------------------------------+--*/
/*  + DECLARE                                                    +  */
/*--+------------------------------------------------------------+--*/
DCL VAR(&FILEANDLIB) TYPE(*CHAR) LEN(  20  )  /* FILE AND LIBRARY   */
DCL VAR(&FILE      ) TYPE(*CHAR) LEN(  10  )  /* FILE               */
DCL VAR(&LIB       ) TYPE(*CHAR) LEN(  10  )  /* LIBRARY            */


/*--+------------------------------------------------------------+--*/
/*  + START OF PROGRAM                                           +  */
/*--+------------------------------------------------------------+--*/

/*--+------------------------------------------------------------+--*/
/*  + INITIALIZE                                                 +  */
/*--+------------------------------------------------------------+--*/
CHGVAR VAR(&FILE      ) VALUE(%SST(&FILEANDLIB  1 10))
CHGVAR VAR(&LIB       ) VALUE(%SST(&FILEANDLIB 11 10))

/*--+--------------------------------+--*/
/*  + CREATE OF DSPPFR FILE IN QTEMP +  */
/*--+--------------------------------+--*/
DSPFD FILE(&LIB/&FILE) TYPE(*MBR) OUTPUT(*OUTFILE) +
                       FILEATR(*PF) OUTFILE(QTEMP/DSPPFR)

    MONMSG MSGID(CPF3012) EXEC(DO)
        SNDPGMMSG MSGID(CPF3012) MSGF(QCPFMSG) MSGDTA(&FILEANDLIB) +
                                               MSGTYPE(*ESCAPE)
    ENDDO

    MONMSG MSGID(CPF3064) EXEC(DO)
        SNDPGMMSG MSGID(CPF3064) MSGF(QCPFMSG) MSGDTA(&LIB)  +
                                               MSGTYPE(*ESCAPE)
    ENDDO

    MONMSG MSGID(CPF3081) EXEC(DO)
        SNDPGMMSG MSGID(CPF3081) MSGF(QCPFMSG) MSGDTA(&LIB)  +
                                               MSGTYPE(*ESCAPE)
    ENDDO


/*--+------------------------------------------------------------+--*/
/*  + M A I N                                                    +  */
/*--+------------------------------------------------------------+--*/
/*--+------------------+--*/
/*  + CALL RPG PROGRAM +  */
/*--+------------------+--*/
OVRDBF FILE(DSPPFR) TOFILE(QTEMP/DSPPFR)

CALL PGM(RDSPPFR) PARM(&FILE &LIB)

DLTOVR FILE(DSPPFR)


/*--+------------------------------------------------------------+--*/
/*  + END OF PROGRAM                                             +  */
/*--+------------------------------------------------------------+--*/
#_EXIT_:
ENDPGM