/*--+------------------------------------------------------------+--*/
/*--+   PROGRAM ID : $SAVSPLF                                    +--*/
/*--+ PROGRAM NAME : CL OF SAVE SPOOLED FILE                     +--*/
/*--+------------------------------------------------------------+--*/
/*--+      VERSION : 1.1 (2000/02/28) CHANGED QSPGETF PARM       +--*/
/*--+                1.0 (1999/04/22)                            +--*/
/*--+------------------------------------------------------------+--*/
/*--+ R510以降で使用するために                                 +--*/
/*--+   25行目&SPLNBRの桁数4を6にする                    +--*/
/*--+   30行目&SH_SPLNOB2の桁数2を4にする                +--*/
/*--+  さらにコマンドSAVSPLFのSPLNBRの桁数4を6にする   +--*/
/*--+------------------------------------------------------------+--*/
PGM PARM(&SPLF &FILEANDLIB &JOB &SPLNBR &MBR)

/*--+------------------------------------------------------------+--*/
/*  + DECLARE                                                    +  */
/*--+------------------------------------------------------------+--*/
/* COMMAND(CVTSPLF) PARAMETERS */
DCL VAR(&SPLF      ) TYPE(*CHAR) LEN(  10  )  /* SPOOL FILE NAME    */
DCL VAR(&FILEANDLIB) TYPE(*CHAR) LEN(  20  )  /* FILE & LIBRARY     */
DCL VAR(&JOB       ) TYPE(*CHAR) LEN(  26  )  /* NAME & USR & NBR   */
    DCL VAR(&JOB_NAM   ) TYPE(*CHAR) LEN(  10  ) /* JOB NAME        */
    DCL VAR(&JOB_USR   ) TYPE(*CHAR) LEN(  10  ) /* JOB USER        */
    DCL VAR(&JOB_NBR   ) TYPE(*CHAR) LEN(   6  ) /* JOB NUMBER      */
DCL VAR(&SPLNBR    ) TYPE(*CHAR) LEN(   4  )  /* SPOOL NUMBER       */
DCL VAR(&MBR       ) TYPE(*CHAR) LEN(  10  )  /* MEMBER             */
DCL VAR(&OUTQANDLIB) TYPE(*CHAR) LEN(  20  )  /* OUTQ & LIBRARY     */

/* SHARED PARAMETERS */
DCL VAR(&SH_SPLNOB2) TYPE(*CHAR) LEN(   2  )  /* SPOOLED NO.(B2)    */
DCL VAR(&SH_MSGDTA ) TYPE(*CHAR) LEN( 256  )  /* MESSAGE DATA       */

/*--+------------------------------------------------------------+--*/
/*  + START OF PROGRAM                                           +  */
/*--+------------------------------------------------------------+--*/
/* PREPARE PARAMETERS */
CHGVAR VAR(&JOB_NAM   ) VALUE(%SST(&JOB         1 10))
CHGVAR VAR(&JOB_USR   ) VALUE(%SST(&JOB        11 10))
CHGVAR VAR(&JOB_NBR   ) VALUE(%SST(&JOB        21  6))

IF (&JOB_NAM *EQ '*         ') DO
    RTVJOBA  JOB(&JOB_NAM) USER(&JOB_USR) NBR(&JOB_NBR)
    CHGVAR VAR(%SST(&JOB    1 10)) VALUE(&JOB_NAM   )
    CHGVAR VAR(%SST(&JOB   11 10)) VALUE(&JOB_USR   )
    CHGVAR VAR(%SST(&JOB   21  6)) VALUE(&JOB_NBR   )
ENDDO

IF ((&MBR *EQ '*SPLF'     )  *OR +
    (&MBR *EQ '          '))  DO
    CHGVAR VAR(&MBR       ) VALUE(&SPLF      )
ENDDO

CHGVAR VAR(%BIN(&SH_SPLNOB2))       VALUE(&SPLNBR)

/*--+------------------------------------------------------------+--*/
/*  + M A I N                                                    +  */
/*--+------------------------------------------------------------+--*/
/* FOR QSPGETF */
CALL   PGM(QSPGETF) PARM(&SPLF       +
                         &FILEANDLIB +
                         &JOB        +
                         &SH_SPLNOB2 +
                         &MBR        )

    MONMSG MSGID(CPF3303) EXEC(DO)
        RCVMSG MSGQ(*PGMQ) RMV(*YES) MSGDTA(&SH_MSGDTA)
        SNDPGMMSG MSGID(CPF3303) MSGF(QCPFMSG)      +
                                 MSGDTA(&SH_MSGDTA) +
                                 MSGTYPE(*ESCAPE)
    ENDDO
    MONMSG MSGID(CPF3342) EXEC(DO)
        RCVMSG MSGQ(*PGMQ) RMV(*YES) MSGDTA(&SH_MSGDTA)
        SNDPGMMSG MSGID(CPF3342) MSGF(QCPFMSG)      +
                                 MSGDTA(&SH_MSGDTA) +
                                 MSGTYPE(*ESCAPE)
    ENDDO
    MONMSG MSGID(CPF4102) EXEC(DO)
        RCVMSG MSGQ(*PGMQ) RMV(*YES) MSGDTA(&SH_MSGDTA)
        SNDPGMMSG MSGID(CPF4102) MSGF(QCPFMSG)      +
                                 MSGDTA(&SH_MSGDTA) +
                                 MSGTYPE(*ESCAPE)
    ENDDO



CHGVAR VAR(&SH_MSGDTA ) VALUE(&MBR        *CAT +
                              &FILEANDLIB      )
SNDPGMMSG MSGID(CPC7305) MSGF(QCPFMSG)      +
                         MSGDTA(&SH_MSGDTA) +
                         MSGTYPE(*COMP  )

/*--+------------------------------------------------------------+--*/
/*  + END OF PROGRAM                                             +  */
/*--+------------------------------------------------------------+--*/
#_EXIT_:
ENDPGM