H*--+--------------------------------------------------------+--*
     H*--+   PROGRAM ID : RDSPFF                                  +--*
     H*--+ PROGRAM NAME : RPG OF DISPLAY FILE FORMAT              +--*
     H*--+--------------------------------------------------------+--*
     H*--+      VERSION : 1.2 (98/10/12) ADDED FIELD TEXT AND F9  +--*
     H*--+              : 1.1 (98/10/05) ADDED "TYPE OF FILE"     +--*
     H*--+              : 1.0 (98/09/20)                          +--*
     H*--+--------------------------------------------------------+--*
     H            Y
      *
     F@DSPFF  CF  E                    WORKSTN
     F                                        @RRN1 KSFILE @SFLFF
     F*
     FDSPFF   IF  E                    DISK
      *
     C*--+--------------------------------------------------------+--*
     C*--+ START OF PROGRAM                                       +--*
     C*--+--------------------------------------------------------+--*
     C                     EXSR SRINIT
     C                     EXSR SRMAIN
     C                     EXSR SREND
      *
     C*--+--------------------------------------------------------+--*
     C*--+ INITIALIZATION                                         +--*
     C*--+--------------------------------------------------------+--*
     C           SRINIT    BEGSR
     C                     EXSR SRCLR
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ MAIN (CONTROL OF DISPLAY PANEL)                        +--*
     C*--+--------------------------------------------------------+--*
     C           SRMAIN    BEGSR
     C           START     TAG
     C                     WRITE@PNLINF
     C                     WRITE@PNLWAIT
     C*
     C                     EXSR SRFF
     C* DISPLAY DETAIL PANEL
     C                     WRITE@PNLINF
     C                     EXFMT@CTLFF
     C*
     C*  (FUNCTION AND ENTER)
     C           *INKC     IFEQ *ON                        F3
     C                     EXSR SREND
     C                     END
     C*
     C           F#NEXT    IFEQ 'NEXT RCD'                 ENTER
     C                     MOVE '        'F#NEXT  8
     C                     EXSR SRCLR
     C                     GOTO START
     C                     END
     C*
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ END OF PROGRAM                                         +--*
     C*--+--------------------------------------------------------+--*
     C           SREND     BEGSR
     C                     SETON                     LR
     C                     RETRN
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ SET DETAIL FROM DSPFF FILE TO SUBFILE                  +--*
     C*--+--------------------------------------------------------+--*
     C           SRFF      BEGSR
     C                     SETOF                     51
     C*
     C           *IN90     DOUEQ*ON
     C                     READ DSPFF                    90
     C           *IN90     IFEQ *OFF
     C                     ADD  1         @RRN1
     C*
     C           @RRN1     IFEQ 1
     C                     MOVE WHFILE    @FILE            FILE
     C                     MOVE WHLIB     @LIB             LIBRARY
     C                     MOVE WHNAME    @RFMT            RECORD
     C                     MOVE WHCRTD    @CRTD            CREATION
     C                     MOVE WHRLEN    @RLEN            RECORD LEN
     C                     SELEC
     C           WHFTYP    WHEQ 'P'
     C                     MOVE 'PHYSICAL'@FTYP            TYPE OF FILE
     C           WHFTYP    WHEQ 'L'
     C                     MOVE 'LOGICAL' @FTYP            TYPE OF FILE
     C           WHFTYP    WHEQ 'D'
     C                     MOVE 'DEVICE'  @FTYP            TYPE OF FILE
     C                     ENDSL
     C                     MOVE WHNAME    Q#NAME 10        RECORD SAVE
     C                     END
     C*
     C           WHNAME    IFNE Q#NAME
     C                     MOVE WHNAME    Q#NAME           RECORD
     C                     READPDSPFF                    90
     C                     MOVE 'NEXT RCD'F#NEXT
     C                     SETON                     51    MESSAGE
     C                     LEAVE
     C                     END
     C*
     C                     Z-ADD@RRN1     @NO              NO
     C                     MOVE WHFLDE    @FLD             FIELD
     C                     MOVE WHFLDT    @TYPE            TYPE
     C                     Z-ADDWHFLDB    @LEN             LENGTH
     C                     Z-ADDWHFLDP    @DEC             DEC
     C                     Z-ADDWHIBO     @STR             STRAT POS
     C           @STR      ADD  WHFLDB    @END             END POS
     C                     SUB  1         @END             END POS
     C                     Z-ADDWHCSID    @CCSID           CCSID
     C                     MOVE WHCHD1    @COLHD           COLHDG
     C*
     C                     SETOF                     31
     C           @TYPE     IFEQ 'P'                        PACK
     C           @TYPE     OREQ 'S'                        ZONE
     C           @TYPE     OREQ 'B'                        BINARY
     C           @TYPE     OREQ 'F'                        FLOAT
     C                     SETON                     31
     C                     END
     C                     MOVE WHFTXT    @TEXT            TEXT
     C*
     C                     WRITE@SFLFF
     C                     END
     C                     ENDDO
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ INITIALIZE OF SUBFILE(@SFLFF   )                       +--*
     C*--+--------------------------------------------------------+--*
     C           SRCLR     BEGSR
     C                     SETOF                     81
     C                     WRITE@CTLFF
     C                     SETON                     81
     C*
     C                     Z-ADD0         @RRN1   60
     C                     ENDSR