H*--+--------------------------------------------------------+--*
     H*--+   PROGRAM ID : RDSPPFR                                 +--*
     H*--+ PROGRAM NAME : RPG OF DISPLAY NUMBER OF PF RECORDS     +--*
     H*--+--------------------------------------------------------+--*
     H*--+      VERSION : 1.0 (98/10/12)                          +--*
     H*--+--------------------------------------------------------+--*
     H            Y
      *
     F@DSPPFR CF  E                    WORKSTN
     F                                        @RRN1 KSFILE @SFLPFR
     F*
     FDSPPFR  IF  E                    DISK
      *
     C*--+--------------------------------------------------------+--*
     C*--+ ACCEPT PARAMETER FROM OTHER PROGRAM                    +--*
     C*--+--------------------------------------------------------+--*
     C           *ENTRY    PLIST
     C                     PARM           @FILE            FILE
     C                     PARM           @LIB             LIBRARY
      *
     C*--+--------------------------------------------------------+--*
     C*--+ START OF PROGRAM                                       +--*
     C*--+--------------------------------------------------------+--*
     C                     EXSR SRINIT
     C                     EXSR SRMAIN
     C                     EXSR SREND
      *
     C*--+--------------------------------------------------------+--*
     C*--+ INITIALIZATION                                         +--*
     C*--+--------------------------------------------------------+--*
     C           SRINIT    BEGSR
     C                     EXSR SRCLR
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ MAIN (CONTROL OF DISPLAY PANEL)                        +--*
     C*--+--------------------------------------------------------+--*
     C           SRMAIN    BEGSR
     C           START     TAG
     C                     WRITE@PNLINF
     C                     WRITE@PNLWAIT
     C*
     C                     EXSR SRPFR
     C* DISPLAY DETAIL PANEL
     C                     WRITE@PNLINF
     C                     EXFMT@CTLPFR
     C*
     C*  (FUNCTION AND ENTER)
     C           *INKC     IFEQ *ON                        F3
     C                     EXSR SREND
     C                     END
     C*
     C           F#NEXT    IFEQ 'OVR10000'                 ENTER
     C                     Z-ADD0         W#CNT
     C                     MOVE '        'F#NEXT  8
     C                     EXSR SRCLR
     C                     GOTO START
     C                     END
     C*
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ END OF PROGRAM                                         +--*
     C*--+--------------------------------------------------------+--*
     C           SREND     BEGSR
     C                     SETON                     LR
     C                     RETRN
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ SET DETAIL FROM DSPPFR FILE TO SUBFILE                 +--*
     C*--+--------------------------------------------------------+--*
     C           SRPFR     BEGSR
     C                     SETOF                     51
     C*
     C           *IN90     DOUEQ*ON
     C                     READ DSPPFR                   90
     C           *IN90     IFEQ *OFF
     C*
     C                     ADD  1         W#CNT
     C           W#CNT     IFGE 10000
     C                     MOVE 'OVR10000'F#NEXT           10000FLG
     C                     SETON                     51    MESSAGE
     C                     READPDSPPFR                   91
     C                     LEAVE
     C                     END
     C*
     C*
     C                     ADD  1         @RRN1
     C*
     C                     Z-ADD@RRN1     @NO              NO
     C                     MOVE MBFILE    @FILNM           FILE
     C                     MOVE MBNAME    @MBR             MEMBER
     C                     MOVE MBLIB     @LIBNM           LIBRARY
     C                     MOVE MBFCDT    @CDT             CREATION
     C                     Z-ADDMBNDTR    @DLTR            DELETE
     C                     Z-ADDMBNRCD    @RCDS            RECORDS
     C           @DLTR     ADD  @RCDS     @TOTAL           TOTAL
     C*
     C                     MOVE MBTXT     @TEXT            TEXT
     C           MBLVLC    IFEQ 'Y'
     C                     MOVE '*YES'    @LVL             LVLCHK
     C                     ELSE
     C                     MOVE '*NO '    @LVL
     C                     END
     C*
     C                     WRITE@SFLPFR
     C                     END
     C                     ENDDO
     C                     ENDSR
      *
     C*--+--------------------------------------------------------+--*
     C*--+ INITIALIZE OF SUBFILE(@SFLPFR  )                       +--*
     C*--+--------------------------------------------------------+--*
     C           SRCLR     BEGSR
     C                     SETOF                     81
     C                     WRITE@CTLPFR
     C                     SETON                     81
     C*
     C                     Z-ADD0         @RRN1   60
     C                     Z-ADD0         W#CNT   60
     C                     ENDSR